# Maintainer: Aaron Griffin <aaron@archlinux.org>
# Contributor: Judd Vinet <jvinet@zeroflux.org>

pkgname=logrotate
pkgver=3.7.8
pkgrel=2
pkgdesc="Rotates system logs automatically"
url='http://cvs.fedora.redhat.com'
arch=('i686' 'x86_64')
license=('GPL')
groups=('base')
depends=('popt' 'cron' 'gzip')
backup=('etc/logrotate.conf')
options=('emptydirs')
#WTF are you doing, Fedora?
_pkgmd5=b3589bea6d8d5afc8a84134fddaae973
#source=("http://cvs.fedora.redhat.com/repo/pkgs/$pkgname/$pkgname-$pkgver.tar.gz/$_pkgmd5/$pkgname-$pkgver.tar.gz"
source=("http://www.sfr-fresh.com/unix/privat/$pkgname-$pkgver.tar.gz"
        'logrotate.conf'
        'logrotate.cron.daily')
md5sums=($_pkgmd5
         '7e85736e40b155e745d6b9d5442483db'
         '8e23d5d4cc29b1e055b24df87e355cdc')

build() {
  cd $srcdir/${pkgname}-${pkgver}
  
  sed -i 's|#define DEFAULT_MAIL_COMMAND .*|#define DEFAULT_MAIL_COMMAND "/usr/bin/mail"|' config.h || return 1
  sed -i "s|CFLAGS = -Wall|CFLAGS = -Wall $CFLAGS|" Makefile || return 1
  sed -i 's|$(BASEDIR)/man|$(BASEDIR)/share/man|' Makefile || return 1
  
  make || return 1
}

package() {
  cd $srcdir/${pkgname}-${pkgver}
  
  make PREFIX=$pkgdir install || return 1
  
  install -Dm644 $srcdir/logrotate.conf $pkgdir/etc/logrotate.conf || return 1
  install -Dm744 $srcdir/logrotate.cron.daily $pkgdir/etc/cron.daily/logrotate || return 1

  install -d $pkgdir/var/log/archive/ || return 1
}

# vim:set ts=2 sw=2 et:
