# Maintainer: Phillip Smith <fukawi2@archserver.org>
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: Thomas Baechler <thomas@archlinux.org>

pkgname=iptables
pkgver=1.4.11.1
pkgrel=1
pkgdesc="A Linux kernel packet control tool"
arch=('i686' 'x86_64')
license=('GPL2')
url="http://www.netfilter.org/"
depends=('glibc' 'bash')
options=('!libtool')
backup=('etc/conf.d/iptables')
source=("http://www.iptables.org/projects/iptables/files/${pkgname}-${pkgver}.tar.bz2"
        'iptables'
        'ip6tables'
        'empty.rules'
        'simple_firewall.rules'
        'confd.iptables')
md5sums=('7de6e1ae7ed8a2025f184763a6a24b9a'
         '89401d6f0cf1de46a455b7be6720a58b'
         '6e0e88c2ed0c3715d1409ee3258a0046'
         '14186bbafe21bb0638c0cb8e0903c829'
         'e53a83bb4d8ac8b7eadd7bd58294751d'
         'c7cf6e4455c228e50d20ce3edd75ee59')

build() {
  cd $srcdir/$pkgname-$pkgver
  
  ./configure \
    --prefix=/usr \
    --with-kernel=usr/src/linux-$(uname -r) \
    --libexecdir=/usr/lib/iptables --sysconfdir=/etc \
    --with-xtlibdir=/usr/lib/iptables \
    --enable-devel --enable-libipq
  
  make
}

package() {
  cd $srcdir/$pkgname-$pkgver
  
  make DESTDIR=$pkgdir install 
  
  install -Dm755 $srcdir/iptables ${pkgdir}/etc/rc.d/iptables
  install -Dm755 $srcdir/ip6tables ${pkgdir}/etc/rc.d/ip6tables
  install -Dm644 $srcdir/empty.rules ${pkgdir}/etc/iptables/empty.rules
  install -Dm644 $srcdir/simple_firewall.rules ${pkgdir}/etc/iptables/simple_firewall.rules
  install -Dm644 $srcdir/confd.iptables ${pkgdir}/etc/conf.d/iptables
}

# vim:set ts=2 sw=2 et:
