# Maintainer: judd <jvinet@zeroflux.org>

pkgname=gdbm
pkgver=1.8.3
pkgrel=2
pkgdesc="GNU database library"
url="http://www.gnu.org/software/gdbm/gdbm.html"
license=('GPL')
arch=('i686' 'x86_64')
groups=('base')
depends=('glibc')
source=("ftp://ftp.gnu.org/gnu/gdbm/$pkgname-$pkgver.tar.gz")
install="$pkgname.install"
options=(!libtool)
md5sums=('1d1b1d5c0245b1c00aff92da751e9aa1')

build() {
  cd $srcdir/$pkgname-$pkgver
  
  ./configure \
    --prefix=/usr \
    --mandir=/usr/share/man \
    --infodir=/usr/share/info || return 1
  
  make prefix=/usr || return 1
}

package() {
  cd $srcdir/$pkgname-$pkgver
  
  make prefix=$pkgdir/usr manprefix=$pkgdir/usr/share/man man3dir=$pkgdir/usr/share/man/man3 infodir=$pkgdir/usr/share/info install || return 1
  
  make prefix=$pkgdir/usr manprefix=$pkgdir/usr/share/man man3dir=$pkgdir/usr/share/man/man3 infodir=$pkgdir/usr/share/info install-compat || return 1
  
  chown root:root $pkgdir/usr/include/{dbm.h,gdbm.h,ndbm.h} || return 1
  chown root:root $pkgdir/usr/share/man/man3/gdbm.3 || return 1
  chown root:root $pkgdir/usr/share/info/gdbm.info || return 1
}

# vim:set ts=2 sw=2 et:
